*SPSS Syntax.
*explanation of the variable names on item level.

*PA = positive affect.
*NA = negative affect.
*MP = Manipulation check, feeling of exclusion.
*sdopen = qualitative indications of topics participants would like to talk with the robot NAO.
*minutes = number of minutes participants would like to talk with the robot NAO, objective preferred length of the conversation.
*sublength = subjective preferred length of a conversation. 
*int_conv = preferred conversation intimacy for the imagined conversation.
*SD = self-disclosure.
*joyful = positive anticipation of a conversation with the robot NAO.
*imag = imagination quality of the conversation with the robot NAO.
*mpag = mind perception agency of the robot NAO.
*mpex = mind perception experience of the robot NAO.
*agenc = perceived competence/agency of the robot NAO.
*comm = perceived warmth/communion of the robot NAO.
*convinc = expected conversation incapability of the robot NAO.
*TA = technology acceptance as one aspect of technology commitment.
*Tcomp = technology competence as one aspect of technology commitment.
*Tcontr = belief in own technology control as one aspect of technology commitment.
*socanx = social anxiety. 
*ucla = current loneliness.
*bucla = retrospective loneliness before the COVID-19 pandemic.

*explanation of the variable names which are scale means.

*Pos_affect = positive affect.
*Neg_affect = negative affect.
*MChck = manipulation check, feeling of exclusion.
*SD_scale =  willingness to self-disclose overall, all items.
*SD_low = willingness to self-disclose positive topics low in intimacy.
*SD_pos = willingness to self-disclose positive topics high in intimacy.
*SD_neg = willingness to self-disclose negative topics high in intimacy.
*anticipation = positive anticipation of a conversation with the robot NAO.
*Imagqu = imagination quality of the imagined conversation with the robot NAO.
*Mind_Agency = perceived mind agency of the robot NAO.
*Mind_Exp = perceived mind experience of the robot NAO.
*competence = perceived competence of the robot NAO.
*warmth = perceived warmth of the robot NAO.
*Convinc = expected conversation incapability of the robot NAO.
*lonel_cur = current loneliness during the beginning of the COVID-19 pandemic.
*lonel_bef = retrospective loneliness before the COVID-19 pandemic.
*SocAnx = social anxiety.
*Tech = technology commitment.
*Diff_lonel = change in loneliness, where higher positive values indicate more loneliness now compared to before the pandemic, while negative values indicate less loneliness now compared
to before the pandemic.
*nb_sdopen = number of proposed conversation topics for a conversation with the robot NAO.
*M_Int = mean topic intimacy of both raters of the qualitatively named conversation topics with the robot NAO.
*Diff_lonel_change = nominal variable of loneliness with three categories of loneliness: more current loneliness than before, equal loneliness, less current loneliness than before..

*compute reliabilities.

*reliability positive affect. 
RELIABILITY
  /VARIABLES=PA1 PA2 PA3 PA4 PA5 
  /SCALE('ALL VARIABLES') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE CORR
  /SUMMARY=TOTAL MEANS.

*reliability negative affect. 
RELIABILITY
  /VARIABLES=NA1 NA2 NA3 NA4 NA5
  /SCALE('ALL VARIABLES') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE CORR
  /SUMMARY=TOTAL MEANS.

*reliability manipulation check, feeling of exclusion.
RELIABILITY
  /VARIABLES=MP1 MP2 MP3 MP4 MP5_re MP6_re
  /SCALE('manipulation check') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE CORR
  /SUMMARY=TOTAL MEANS.


*reliability self-disclosure scale overall. 
RELIABILITY
  /VARIABLES=SD1 SD2 SD3 SD4 SD5 SD6 SD7 SD8 SD9 SD10 SD11 SD12 SD13 SD14 SD15 SD16
  /SCALE('Self-Disclosure overall') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE CORR
  /SUMMARY=TOTAL MEANS.

*reliability self-disclosure positive topics low in intimacy. 
RELIABILITY
  /VARIABLES=SD1 SD2 SD3 SD4 SD7 SD11 SD12 SD16
  /SCALE('lowSD') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.


**reliability self-disclosure positive topics high in intimacy. 
RELIABILITY
  /VARIABLES=SD5 SD6 SD9 SD10
  /SCALE('highposSD') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

**reliability self-disclosure negative topics high in intimacy. 
RELIABILITY
  /VARIABLES=SD8 SD13 SD14 SD15
  /SCALE('highnegSD') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

*reliability positive anticipation of a conversation with the robot. 
RELIABILITY
  /VARIABLES=joyful1 joyful2 joyful3
  /SCALE('anticipation') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

*imagination quality of the conversation. 
RELIABILITY
  /VARIABLES= imag1_re imag2 imag3 imag4 
  /SCALE('imagination quality') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.
    
*reliability mind agency.
RELIABILITY
  /VARIABLES=mpag1 mpag2 mpag3 mpag4 mpag5 mpag6
  /SCALE('Mind_Agency') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

    
*reliability mind experience.
RELIABILITY
  /VARIABLES=mpex1 mpex2 mpex3 mpex4 mpex5 mpex6 
  /SCALE('Mind_Experience') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.
    
*reliability competence/agency.
RELIABILITY
  /VARIABLES=agenc1 agenc2 agenc3 agenc4 agenc5 agenc6 agenc7 
  /SCALE('agency') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

*reliability warmth, communion.
RELIABILITY
  /VARIABLES=comm1 comm2 comm3 comm4 comm5 comm6 comm7 
  /SCALE('warmth communion') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

*reliability expected conversation incapability of the robot.
RELIABILITY
  /VARIABLES=convinc1 convinc2 convinc3 
  /SCALE('conversation incapability') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.


*reliability technology commitment.
RELIABILITY
  /VARIABLES=TA1 TA2 TA3 TA4 Tcomp1_re Tcomp2_re Tcomp3_re Tcomp4_re Tcontr1 Tcontr2 Tcontr3 Tcontr4
  /SCALE('technology commitment') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

*reliability social anxiety.
RELIABILITY
  /VARIABLES=socanx1 socanx2 socanx3 socanx4_re socanx5 socanx6
  /SCALE('social anxiety') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

*reliability current loneliness.
RELIABILITY
  /VARIABLES=ucla1 ucla2 ucla3
  /SCALE('current loneliness') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

*reliability loneliness before the COVID-19 pandemic.
RELIABILITY
  /VARIABLES=bucla1 bucla2 bucla3
  /SCALE('retrospective loneliness') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

*ICC Rating 1-7 of the topic intimacy.
RELIABILITY
  /VARIABLES=sdopenR1_1 sdopenR2_1
  /SCALE('overall intimacy rating') ALL
  /MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE CORR
  /SUMMARY=TOTAL MEANS COV CORR
  /ICC=MODEL(RANDOM) TYPE(CONSISTENCY) CIN=95 TESTVAL=0.

*computing the scales. 

COMPUTE Pos_affect = MEAN (PA1, PA2, PA3, PA4, PA5).
VARIABLE LABELS Pos_affect 'positive affect'.

COMPUTE Neg_affect = MEAN (NA1, NA2, NA3, NA4, NA5).
VARIABLE LABELS Neg_affect 'negative affect'.

COMPUTE MChck = MEAN (MP1, MP2, MP3, MP4, MP5_re, MP6_re).
VARIABLE LABELS MChck 'manipulation check feeling of exclusion'.

COMPUTE SD_scale = MEAN (SD5, SD6, SD8, SD9, SD10, SD13, SD14, SD15, SD1, SD2, SD3, SD4, SD7, SD11, SD12, SD16).
VARIABLE LABELS SD_scale 'Self-Disclosure overall'.

COMPUTE SD_low = MEAN (SD1, SD2, SD3, SD4, SD7, SD11, SD12, SD16).
VARIABLE LABELS SD_low 'Self-Disclosure positive low in intimacy'.

COMPUTE SD_pos = MEAN (SD5, SD6, SD9, SD10).
VARIABLE LABELS SD_pos 'Self-Disclosure positive high in intimacy'.

COMPUTE SD_neg= MEAN (SD8, SD13, SD14, SD15).
VARIABLE LABELS SD_neg 'Self-Disclosure negative high in intimacy'.

COMPUTE anticipation = MEAN (joyful1, joyful2, joyful3).
VARIABLE LABELS anticipation 'anticipation'.

COMPUTE Imagqu = MEAN (imag1_re, imag2, imag3, imag4).
VARIABLE LABELS Imagqu 'imagination quality'.

COMPUTE Mind_Agency = MEAN (mpag1, mpag2, mpag3, mpag4, mpag5, mpag6).
VARIABLE LABELS Mind_Agency 'Mind_Agency'.

COMPUTE Mind_Exp = MEAN (mpex1, mpex2, mpex3, mpex4, mpex5, mpex6).
VARIABLE LABELS Mind_Exp 'Mind_Experience'.

COMPUTE competence = MEAN (agenc1, agenc2, agenc3, agenc4, agenc5, agenc6, agenc7).
VARIABLE LABELS competence 'competence, agency'.    

COMPUTE warmth = MEAN (comm1, comm2, comm3, comm4, comm5, comm6, comm7).
VARIABLE LABELS warmth 'warmth, communion'.    

COMPUTE Convinc = MEAN (convinc1, convinc2, convinc3).
VARIABLE LABELS Convinc 'conversational incompetence'.   

COMPUTE lonel_cur = MEAN (ucla1, ucla2, ucla3).
VARIABLE LABELS lonel_cur 'current loneliness'.  
 
COMPUTE lonel_bef = MEAN (bucla1, bucla2, bucla3).
VARIABLE LABELS lonel_bef 'retrospective loneliness before the COVID-19 pandemic'.   

COMPUTE SocAnx= MEAN (socanx1, socanx2, socanx3, socanx4_re, socanx5, socanx6).
VARIABLE LABELS SocAnx 'Social Anxiety'.   
EXE. 

COMPUTE Tech = MEAN (TA1, TA2, TA3, TA4, Tcomp1_re, Tcomp2_re, Tcomp3_re, Tcomp4_re, Tcontr1, Tcontr2, Tcontr3, Tcontr4).
VARIABLE LABELS Tech 'technology commitment'.
EXE. 

*Intimacy ratings.
*compute the mean of the two independent raters for the topic intimacy.
COMPUTE M_Int = MEAN (sdopenR1_1, sdopenR2_1).
VARIABLE LABELS M_Int 'mean topic intimacy of both raters'.  
EXE. 

*compute the change in loneliness variable as current loneliness minus loneliness before the COVID-19 pandemic.
COMPUTE Diff_lonel=lonel_cur-Lonel_bef.
EXECUTE.


*preparing the loneliness measure to check how many people report overall lower loneliness during the pandemic, higher loneliness during the pandemic or the same loneliness during the pandemic than before. 
RECODE Diff_lonel (Lowest thru -0.1=-1) (0.1 thru Highest=1)  (0=0) INTO Diff_lonel_change.
VARIABLE LABELS  Diff_lonel_change 'change in loneliness'.
EXECUTE.

*change in loneliness measure as three categories.
VARIABLE LEVEL  Diff_lonel_change(NOMINAL).
VALUE LABELS Diff_lonel_change
  -1.00 'loneliness higher before the COVID-19-pandemic'
  .00 'no change in loneliness'
  1.00 'current loneliness higher than before the COVID-19 pandemic'.
EXECUTE.


*Descriptive statistics. 

*how many participants are in which condition. 
FREQUENCIES VARIABLES=condition
  /ORDER=ANALYSIS.
*condition. 


*sex, German language skills, occupation, and how many participants know the robot NAO. 
FREQUENCIES VARIABLES=language occupation knowrobot_yn
  /ORDER=ANALYSIS.

*how well do participants know the robot NAO. 
DESCRIPTIVES VARIABLES=knowrobot
  /STATISTICS=MEAN STDDEV RANGE MIN MAX.
FREQUENCIES VARIABLES=knowrobot
  /ORDER=ANALYSIS.



*descriptive statistics on the change in loneliness measure in three categories.
FREQUENCIES VARIABLES=Diff_lonel_change
  /ORDER=ANALYSIS.
*Preliminary Analyses.

*Manipulation check: test if people feel more excluded in the exclusion condition compared to the other conditions.
UNIANOVA MChck BY condition
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /POSTHOC=condition(TUKEY GH) 
  /PRINT=HOMOGENEITY DESCRIPTIVE ETASQ PARAMETER GEF
  /CRITERIA=ALPHA(.05)
  /DESIGN=condition.

*T-test does loneliness differ significantly when comparing current and retrospective loneliness before the COVUD-19 pandemic?. 
T-TEST PAIRS=lonel_cur WITH lonel_bef (PAIRED)
  /CRITERIA=CI(.9500)
  /MISSING=ANALYSIS.

*main analysis.

*main analysis with inclusionary status as independent variable and willingness to self-disclose, preferred intimacy, perceived warmth, perceived experience and perceived agency as dependent variables. 
GLM SD_scale int_conv warmth Mind_Exp Mind_Agency BY condition
   /CONTRAST(condition)=Simple
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /POSTHOC=condition(TUKEY GH) 
  /PRINT=HOMOGENEITY DESCRIPTIVE ETASQ PARAMETER GEF
  /CRITERIA=ALPHA(.05)
  /DESIGN= condition.

*exploratory correlation analysis. 

CORRELATIONS
  /VARIABLES=lonel_cur Lonel_bef Diff_lonel MChck SD_scale SD_low SD_pos SD_neg int_conv warmth Mind_Agency 
    Mind_Exp competence M_Int nb_sdopen anticipation minutes sublength
  /PRINT=TWOTAIL NOSIG
  /MISSING=PAIRWISE.
*Supplemental Material.







*Supplemental Material. 

*Does age differ between the conditions?.
UNIANOVA age BY condition
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /POSTHOC=condition(TUKEY GH) 
  /PRINT ETASQ DESCRIPTIVE PARAMETER HOMOGENEITY
  /CRITERIA=ALPHA(.05)
  /DESIGN=condition.
*age was deleted to anonymize data. 

*does the gender distribution differ between the conditions?.
CROSSTABS
  /TABLES=condition BY gender
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ 
  /CELLS=COUNT EXPECTED ROW COLUMN 
  /COUNT ROUND CELL.
*gender was deleted to anonymize data. 

*exploratory MANOVA to check if there are differences in the conditions regarding supposed covariates. 
GLM  Pos_affect Neg_affect lonel_cur lonel_bef Diff_lonel SocAnx Tech Imagqu Convinc  BY condition
  /CONTRAST(condition)=Simple
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /POSTHOC=condition(TUKEY GH) 
  /PRINT=HOMOGENEITY DESCRIPTIVE ETASQ PARAMETER GEF
  /CRITERIA=ALPHA(.05)
  /DESIGN= condition.

*explorative Analysis MANCOVA with the main dependant variables and inclusionary status as independant variable and positive as well as negative affect as covariates.
GLM SD_scale int_conv warmth Mind_Exp Mind_Agency BY condition
   WITH Neg_affect Pos_affect 
   /CONTRAST(condition)=Simple
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /PRINT=DESCRIPTIVE ETASQ PARAMETER HOMOGENEITY
  /CRITERIA=ALPHA(.05)
  /DESIGN= Neg_affect Pos_affect condition.

*exploratory MANOVA for the additional dependent variables also depicted in the correlational analysis in the article.
GLM M_Int nb_sdopen minutes sublength competence anticipation BY condition
   /CONTRAST(condition)=Simple
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /POSTHOC=condition(BONFERRONI SIDAK) 
  /PRINT=DESCRIPTIVE ETASQ PARAMETER HOMOGENEITY
  /CRITERIA=ALPHA(.05)
  /DESIGN= condition.

*MANOVA with inclusionary status as independent variable and the three self-disclosure subscales as dependent variables.
GLM SD_low SD_pos SD_neg BY condition
  /CONTRAST(condition)=Simple
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /POSTHOC=condition(TUKEY GH) 
  /EMMEANS=TABLES(condition) COMPARE ADJ(BONFERRONI)
  /PRINT=DESCRIPTIVE ETASQ PARAMETER GEF
  /CRITERIA=ALPHA(.05)
  /DESIGN= condition.

